` fcat
` Scriptol example by D.G. Sureau
` Concatenating two text files


void usage()
	print "fcat - scriptol.org"
	print "usage: fcat infile1 infile2 outfile"
	print "       outfile and infile1 or infile2 must be different"
	exit()
return

int main(int argsize, array arg)

	if argsize <> 4 ? usage()

	text fname1 = arg[1]
	text fname2 = arg[2]

	if arg[3] in array(fname1, fname2) ? usage()

	array in1
	in1.load(fname1)
	if in1.size() = 0 ? die (fname1 + " not found")

	array in2
	in2.load(fname2)
	if in2.size() = 0 ? die (fname2 + " not found")

	` some operations on arrays
	if in1 = in2 
		if fname1 = fname2
			print "one takes the same and one recommences!"
		else
			print fname1, "and", fname2, "are identical!"
		/if
	else
		if in1 # in2 :     ` composite if on intersection of two lists
		= in1 : print "Oh, $fname1 is a part of $fname2!"
		= in2 : print "Oh, $fname2 is a part of $fname1!"
		/if
	/if

` now, writing the two files into one

	array outList = in1 + in2
	outList.store(arg[3])
	error ? die ("enable to open " + arg[3].toText())
	print arg[3], "created"

return 0

main($argc, $argv)